XFER4171 - Direct File Transfer between HP71 and HP41 computer.
Copyright 1988 by Michael Markov

XFER4171 consists of two complementary programs, XFER41 and XFER71 that run on
the HP71 and HP41, respectively. These programs allow you to transfer files
and data freely between the two machines, to include HP41 PRogram files,
which are stored in a dedicated HP71 text file called PR41, TEXT (AScii) files,
Extended Memory Data files, and data stored in data registers such as R00 - R??.

This file documents these programs and provides user instructions.

HP71 REQUIRES EDLEX AND THE HPIL MODULE

HP41 REQUIRES THE HPIL MODULE AND HP82183A EXTENDED I/O MODULE.
Obviously, you also need Extended Memory in order to transfer AScii (TEXT) or
data files. HP41CX capability is assumed.

THE "PR41" TEXT FILE IS ASSUMED TO EXIST IN THE HP71. It is used to
store HP41 program files in the format required by INP and OUTP. It should be
created with CREATE TEXT PR41 if it does not already exist.

USER INSTRUCTIONS:
To insure trouble-free operation, type RESET HPIL on the HP71, and
turn it OFF. Turn the HP41 off, and connect the HP41 to the HP71.
You should NOT connect other peripherals in the loop, since it slows
communications on the loop. In particular, avoid connecting a thermal
printer, since the printer mode switch position / presence affects HP41
flags and output modes.

You may leave the HP71 off, or press [ON]. DO NOT RUN PROGRAMS, AND DISABLE 
THE STARTUP OPTION IF YOU CHOOSE TO LEAVE THE HP71 OFF. "Wake-up" conditions
w/o STARTUP minimize problems. DO NOT PRESS KEYS OR OTHERWISE LOAD STUFF INTO
THE INPUT BUFFER.

Turn the HP41 ON, and XEQ any of the HP41 routines listed below. Keep in mind
that most of the routines require a filename in the alpha register. See below.

Thereafter, you may XEQ other routines, as desired. You should not have
to repeat the above initialization routine unless some error occurs.

The HP71 is forced into device mode by the HP41. No action needs be
taken on the HP71. HOWEVER, the HP71 may not be running programs or be
in CALC mode. It is possible to check HP71 status to determine whether
it is "busy" using the REQUEST (HP71) instruction and INSTAT (HP41).
Such testing is NOT implemented because otherwise the size of the 
HP41 control programs grows rapidly.

The HP41 sends out IFC frames to takeover control of the loop, then
puts the HP71 into REMOTE mode and tells it to CALL XFER41...
thereafter, information is exchanged to tell the HP71 what to do, ie.,
the option number and filename. The carefully choreographed exchange
continues until the job is done. To the extent possible, work is done
by the HP71 to minimize HP41 overhead.

Currently, the following options are available:
[0] Send HP71 directory to the HP41. XEQ "DIR71" on the HP41. Alpha reg. : N/A
[1] Download an HP41 program file from HP71. XEQ "LOADP" on the HP41.
    Alpha reg. must contain the name of the file to be downloaded, 7 chars. max
[2] Upload an HP41 program file to the HP71. XEQ "STOP " on the HP41.
    Alpha reg. must contain the name of the file to be uploaded, 7 chars. max
[3] Upload an HP41 TEXT file.     XEQ "UPTXT" on the HP41.
    Alpha reg. must contain the name of the file to be uploaded, 7 chars. max
[4] Download an HP41 TEXT file.     XEQ "DNTXT" on the HP41.
    Alpha reg. must contain the name of the file to be downloaded, 7 chars. max
     If a record is more than 254 bytes long, it is subdivided into 254
     byte records (max allowed by HP41).
[5] Send HP41 printed output to an HP71 TEXT file. XEQ "PR71" on the HP41.
    Alpha reg. must contain the name of the HP71 text file into which the
    "printed" output is to be stored. 8 chars. max
   The HP71 will continue to store output until you XEQ "PREND".
   In this mode, you can upload the contents of data registers with
   PRREG, PRREGX, PRSTK, ect. KEEP IN MIND THAT THE DISPLAY MODE
   CONTROLS SIGNIFICANT DIGITS... F/E 9 (FIX/ENG 9) OR SCI 9 MODES ARE
   REQUIRED TO INSURE MAXIMUM PRECISION  FOR THE INFORMATION TO BE
   UPLOADED. ==>CAUTION, NNN'S MAY BE NORMALIZED.
   F/E 9 mode can be set with the FE routine. Alternatively, use the
   F/E keyword (CCD ROM).
NOTE THAT YOU MUST USE THE "PR71" OPTION IF YOU WANT TO UPLOAD THE CONTENTS
OF DATA REGISTERS OR DATA FILES IF ANY STRINGS ARE STORED IN THE SUBJECT 
FILE OR DATA REGISTERS.

[6] Purge an HP41 program file out of PR41.  XEQ "PURPR" on the HP41.
    Alpha reg. must contain the name of the file to be purged. 7 chars. max.

PURPR allows you to purge ONLY HP41 PRogram files. Other HP71 files can be 
purged more efficiently using the HP71 PURGE <filename> instruction.
[7] Upload an HP41 data file from Extended Memory to an HP71 SDATA file.
    XEQ "UPDAT" on the HP41. CAUTION: FOR NUMERIC DATA ONLY!
    Alpha reg. must contain the name of the file to be uploaded. 7 chars. max.

[8] Download an HP71 SDATA file and stuff it into an Extended Memory data file.
    XEQ "DNDAT" on the HP41. (numeric data only)
    Alpha reg. must contain the name of the file to be downloaded. 7 chars. max

You can verify the validity of the HP41 program checksum, the last two bytes
sent by OUTP as follows: (incoming)
IF HTD(A$[1,4])#(LEN(A$)-6)/2 THEN 'ERROR'
S=0 @ FOR I=1 TO LEN(A$)-3 STEP 2 @ S=S+HTD(A$[I,I+1]) @ NEXT I 
IF A$[LEN(A$)-1]#DTH$(S)[4]  THEN ERROR...

Given the above information, it should be relatively easy to write a
software development system for the HP41 that runs on the HP71. XFER41
and the associated HP41 programs in the XFER71 file take care of uploading and
downloading the stuff directly. The HP71 could just as easily store the data on
mass storage for indirect transfers. See TPRP41D (HP75) on CHHU03. TPRP41D
implements a simple scheme for translating HP41 program hex code to the
equivalent RPN mnemonics. This could be improved upon by writing a LEX file.

SDATA files consist of an integer multiple of 8 byte registers. The
least significant digit is "lost" when using HP41 seven byte registers. Also,
the HP71 STD and (FIX / SCI / ENG ) (10 or 11) modes can cause the ascii
representation of numbers sent by OUTPUT to be incompatible with IND, because
IND cannot handle a mantisa with more than 10 digits...

HP71 TEXT files have 2 byte "length-of-record" headers, while the HP41
supports only 1 byte "length-of-records". HP41 text files therefore
take less room than equivalent HP71 files. HOWEVER: HP41 text file
records cannot exceed 254 bytes in length.
0600 CALL XFER41
0610 SUB XFER41
0620 DIM F$,A$[4500],B$[4500] @ REAL N ! we want to be able the largest program 
0630 STD @ CONTROL OFF @ STANDBY ON  ! device mode, wait forever if need be
                                     ! for HP-IL response.
0640 ASSIGN #1 TO PR41
* now that initial setup is done, find out the desired option
0650 ENTER :LOOP ;N$ @ IF N$='0' THEN 'OPT0' ! DIR71 does not need a filename
0660 ENTER :LOOP ;F$ ! Get the filename, or whatever
* filenames are 7 chars. maximum. We do not (yet) handle name,newname choices
0670 F$[8]='' @ GOTO 'OPT'&N$  ! effectively, GTO IND <option>
0690 'OPT1': RESTORE #1,0 ! download a program named F$ to the HP41
0700 FOR I=0 TO FILESZR('PR41')-1 ! find it in PR41
0710 READ #1;A$ @ IF A$[1,7]=F$ THEN 730
0720 NEXT I
0730 OUTPUT :LOOP ;A$[8] ! and send it out on the loop
0740 GOTO 1170 ! common ending
0750 'OPT2': ! Get an HP41 program from the loop
0760 ENTER :LOOP ;A$ ! get it
0770 RESTORE #1 ! find it, if it is in PR41
0780 FOR I=0 TO FILESZR('PR41')-1
0790 READ #1;B$
0800 IF B$[1,7]=F$ THEN REPLACE #1,I;F$&A$ @ GOTO 1170 ! if it is there, update
0810 NEXT I @ PRINT #1;F$&A$ @ GOTO 1170 ! or just append it to the file.
0820 'OPT3': E$=CHR$(255) @ E$=E$&E$&E$ @ E$=E$&E$ ! Upload a text file from the HP41
0830 ON ERROR GOTO 850 ! create the file, if needed.
0840 CREATE TEXT F$
0850 OFF ERROR @ ASSIGN #1 TO F$ @ RESTORE #1,99999 ! assign a pointer and 
move it to the end of the file so that text is appended.
* then, get each record until the HP41 sends a 6 byte record (hex :FF FF FF FF FF FF)
* our chosen "end of file" message.
0860 ENTER :LOOP ;A$ @ IF A$=E$ THEN 940
0870 PRINT #1;A$ @ GOTO 860 ! append to file F$ and go get the next record
*********************************
* Download a text file named F$ to the HP41
0880 'OPT4':
0890 ASSIGN #1 TO F$ @ RESTORE #1
0900 ON ERROR GOTO 930
0910 READ #1;A$         read a record until end of file error
0919 IF LEN(A$)>254 THEN OUTPUT :LOOP ;A$[1,254] @ A$=A$[255] @ GOTO 919 ! max rec. len is 254
0920 OUTPUT :LOOP ;A$ @ GOTO 910 ! send it to the 41
0930 OFF ERROR @ OUTPUT :LOOP ;CHR$(255)&CHR$(255) ! send the chosen 'end of file' message.
0940 OUTPUT :LOOP ;F$ @ GOTO 1170 ! restore the filename in alpha, for whatever good it does you
0950 'OPT0':   ! send a "DIRectory" of available files to the HP41
0960 ASSIGN #1 TO PR41 @ FOR I=0 TO FILESZR('PR41')-1 ! starting with the PRogram files
0970 READ #1;A$ @ B$=STR$(HTD(A$[8,11])) @ B=LEN(B$) @ B$='000'[0,3-B]&B$ ! decode length
0980 A$=A$[1,7]&' P'&B$ @ DISP A$ @ OUTPUT :LOOP ;A$ ! format output and send it 
0990 WAIT 1 @ NEXT I @ I=0 ! then, scan main memory for TEXT or SDATA files
1000 I=I+1 @ B$=CAT$(I) @ IF B$='' THEN 1070 ! exit when CAT$="", end of main
1010 B=B$[12,16]='TEXT '
* see above for lenght diff between HP41 and HP71 text file lengths.
1020 IF B THEN B$[12,16]=' TEXT' @ B=CEIL((VAL(B$[17,22])-FILESZR(B$[1,8]))/7) @ GOTO 1050
1030 IF B$[12,16]#'SDATA' THEN 1000 ! if not TEXT or SDATA, then do next file entry
1040 B=CEIL(VAL(B$[17,22])/8) ! SDATA file length in registers
1050 B$[9]=B$[13,13]&'000' @ B1$=STR$(B) ! format output
1060 B$[13-LEN(B1$)]=B1$ @ DISP B$ @ OUTPUT :LOOP ;B$ @ GOTO 1000 ! and send it to the HP41
1070 OUTPUT :LOOP ;'' @ GOTO 1170 ! end of "DIR71"
1080 'OPT6': ASSIGN #1 TO PR41 ! purge an HP41 PRogram file from PR41
1090 FOR I=0 TO FILESZR('PR41')-1 @ READ #1;A$ ! find it
1100 IF A$[1,7]=F$ THEN DELETE #1,I @ GOTO 1170 ! and delete if found
1110 NEXT I @ GOTO 1170 ! or do clean exit
1120 'OPT5': ON ERROR GOTO 1140 ! here is how we pretend to be a printer
1130 E$=CHR$(255)&CHR$(255) @ CREATE TEXT F$ ! create the file if it does not exist
1140 OFF ERROR @ ASSIGN #1 TO F$ @ RESTORE #1,99999 ! we want to append stuff, not overwrite
1150 ENTER :LOOP ;A$ @ IF A$=E$ THEN 1170 ! catch loop data, test for 'printer mode end' message
1160 DISP A$ @ PRINT #1;A$ @ GOTO 1150 ! save it, display it and repeat as needed
1170 OFF ERROR @ STANDBY OFF @ END ! exit for XFER41 routines, we want to restore normal
* operation, to the extent possible.
*******************************
1180 'OPT7': ENTER :LOOP ;I ! get a datafile, starting with # regs.
1185 ON ERROR GOTO 1200
1190 CREATE SDATA F$,I ! create it, if needed
1200 OFF ERROR @ ASSIGN #1 TO F$ @ RESTORE #1,0 ! set pointer
1210 FOR K=1 TO I @ ENTER :LOOP ;N @ PRINT #1,K-1;N @ DISP N @ NEXT K ! and fill it until done
1220 OUTPUT :LOOP ;F$ @ GOTO 1170 ! return the file name to the HP41
************************
* This is the tough one, sending numeric data to the HP41 from a SDATA file
1230 'OPT8': ASSIGN #1 TO F$ @ ENTER :LOOP ;L ! get available room from the HP41
1235 ON ERROR GOTO 1250
1240 RESTORE #1,0 @ FOR I=0 TO 601 @ READ #1,I;K @ NEXT I ! find out the file length
1250 OFF ERROR @ OUTPUT :LOOP ;F$ ! return the file name back to the HP41
1251 OUTPUT :LOOP ;MIN(I,L) @ SCI 9 ! send the HP41 how many registers will be
* sent, and set display format for compatibility with IND
* Then, send the specified number of registers to the 41
* restricting the range of numbers per the capacity of HP41 normalized numbers
1260 FOR K=0 TO I-1 @ READ #1,K;N @ OUTPUT :LOOP ;MIN(MAX(N,1.E-99),9.9999999E+99) @ NEXT K
1270 STD @ GOTO 1170

**********************************
**************************************
* the following addresses XFER71, the HP41 control program:
***************************

The key to this information exchange is that the HP71 will give-up control of
the loop under circumstances that are well documentented in the HP82401A HP-IL
module manual, see pages 52-67.
This allows us to orchestrate information exchange with relative ease. 

Note that there is no error testing done to insure proper operation. The reason
is that the HP41 does not have sufficient memory to spare for the job.
Therefore, it is very important to make sure that the HP71 ENTERs information
whenever the HP41 is OUTputing data, and vice-versa. Also, it is essential to
insure that the data being exchanged has a known format. The presence of
embedded carriage-return & linefeed is of particular concern since it may
cause premature termination of the standard ENTER statment.

Finally, it is important to keep in mind the limitations of IND and of the
equivalent ENTER :LOOP;B. European "," radix with flag 28 clear or group
separators with flag 29 set could greatly complicate information exchange,
mandating the use of tricky IMAGE statements, with the associated penalty of
much slower information exchange.

The performance of the HP71 as a mass storage device for the HP41 is quite 
good - comparable to using a RAMDISK. HP71 keywords exist that, with minor
modifications, could greatly speed-up finding the desired program files. 
This will be done whenever I find some time to do the job.

Keep in mind that these routines are only a first attempt, and were written in
less than week. There should be room for considerable improvement. Still, they
have worked surprizingly well for me. ENJOY!  Mike Markov 88/05/31
 01*LBL "DNTXT"         Download a text file from the HP71
 02 XEQ 99     grab control of the loop
 03 "4"        tell HP71 what you want it to do
 04 XEQ 90     and get the filename back into alpha, send it to HP71
 05 EMROOM     how much room do we have?
 06 CRFLAS     grab all that is available (we assume it is enough)
* Actually, we should send the information to the HP71, and find out if it is
* enough, then issue suitable error messages.. Instead, we take what we can,
* and error out only then. I prefer to assume the user will take care of
* making sure the file is small enough to fit in available extended memory.
 07 CLX        set pointer to start of file
 08 SEEKPTA
 09 "  "       F2 FF FF  set-up for end of file test
 10 ASTO X     which we will do in the stack
 11*LBL 13     the loop to download the text
 12 INACL      get text from the HP71. Sets flag 17 if not end of record, else clears it
* we could also send a counter at the start of each record, which would be read
* with IND, if we do not have the Extended I/O ROM. But that would mean we 
* could not take control without considerable effort...
* also, it could cause problems due to the limitations of INA, no nulls, ect...
 13 ATOX       get rid of dummy prefix
 14 ASTO X     overwriting prefix, which we do not need
 15 X=Y?       is this  FF FF, our chosen end of file marker?
 16 GTO 12     yes, quitting time!
 17 RDN        set-up stack for next test
 18 FS? 09     was flag 17 set last time we INACLed?
 19 APPCHR     yes, append to record
 20 FC?C 09    if not, it is a new record
 21 APPREC     so append as new record
 22 FS? 17     store status of flag 17 in flag 09, since INACL will change 
 23 SF 09      flag 17  before we add the contents of alpha to the text file
 24 GTO 13     and repeat until done.
 25*LBL 12     quitting time!
 26 XEQ 10     restore  filename to alpha (should be just INA)
 27 FLSIZE     now, to recover unused extended memory, we compute
 28 ASROOM     the minimum file size we can live with
 29 7          convert bytes to registers
 30 /
 31 INT
 32 -
 33 RESZFL     and resize accordingly
 34 RTN        done, at last!
 35*LBL "UPTXT"         The routine to upload text to the HP71
 36 XEQ 99     see above
 37 "3"
 38 XEQ 90
 39 0
 40 SEEKPTA    set pointer to start of file
 41*LBL 15     the loop for sending the text to the HP71
 42 CLA        not needed, should be omited
 43 SF 25      ignore error, which will occur at end of file.
 44 GETREC     get record, set or clear flag as appropriate
 45 FC?C 25    was flag 25 cleared by end of file error?
 46 GTO 14     yes, we are done
 47 OUTA       no, send the data to the HP71. Next, sends CR,LF if flag 17 is clear
* In this application, OUTA and INACL complement each other nicely, insofar
*as setting or clearing flag 17 goes. However, keep in mind that OUTA does NOT
* send out all possible characters. For special characters, it may be
* neccessary to use other keywords, as required.
 48 GTO 15     repeat until done
 49*LBL 14     now, we tell the HP71 we are finished
 50 "      "   F6 FF FF FF FF FF FF (our chosen end of file)
 51 OUTA
 52*LBL 10     not required, XEQ 10 should be replaced with INA
 53 INA        get the filename back
 54 RTN        and we are done
 55*LBL "STOP"          store an HP41 program into the HP71
 56 XEQ 99     see above
 57 "2"
 58 XEQ 90
 59 OUTP       send the program as a hexadecimal string
 60 13         send carriage return 
 61 OUTXB
 62 10         and linefeed to terminate the ENTER statement
 63 OUTXB
 64 RTN        done. Easy, wasn't it?
* there should be a better (shorter)  way to terminate. Maybe CLA, CF 17, OUTA,
* or SF 21, PRBUF (should work, since we invoke MANIO mode).
 65*LBL "LOADP"         Load an HP41 program from the HP71 into the HP41.
 66 XEQ 99     (replaces the last program in HP41 memory)
 67 "1"        option
 68 XEQ 90     routine  processing, see above
 69 TAD        HP71 address is in X, from set-up routine (LBL 99, LBL 90). 
 70 96         make it a talker and tell it to send data (SDA frame)
 71 SEND       (RDY 96 = 96 SEND = SDA)
 72 INP        intercepts the data and loads it into program memory
 73 RTN        done!
* For some reason that is unclear to me, INP does not work without the SDA.
* I assume that HP deliberately refrained to prevent potential problems with
* interfaces such as modems, RS-232, HP-IB, ect.
 74*LBL 99     Routine to grab control of the loop.
 75 144        decimal value for IFC (InterFace Clear)
 76 SEND       send IFC several times to give the HP71 the opportunity to
 77 SEND       wake-up, configure itsel, and give-up control of the loop
 78 SEND
 79 SEND
 80 SEND
 81 SEND
 82 SEND
 83 SEND
 84 SEND
 85 SEND
 86 CLRLOOP    clear the loop, resetting all peripherals
 87 3          AID for the HP71
 88 FINDAID    what is the loop address of the 71?
 89 SELECT     make it the primary device
 90 MANIO      to insure that all data exchanged with printer functions are
* sent to the primary device, your HP71
 91 REMOTE     this puts the HP71 into REMOTE mode. Strings sent to the HP71
* will be executed as BASIC commands
 92 ASTO T     Save the contents of the ALPHA registers, up to 12 characters
 93 ASHF       into the stack.
 94 ASTO Z     carefully preserving the loop address of the HP71 in reg. X
 95 "CALL XFER41"     The basic instruction to be executed.
* Note that the quotes are added by PRP. Quotes are not needed in the alpha reg.
 96 CF 17      so that the following OUTA will send End-Of-Line (Carriage
 97 OUTA       return, Linefeed) following the instruction
 98 NOTREM     cancel REMOTE mode. HP71 to handle further data as data, not
* basic instructions!
 99 LAD        tell HP71 to become a Listener
100 RTN        this allows us to tell it what to do next.
101*LBL 90     routine to tell the HP71 what to do
102 OUTA       send option specified in the alpha register
103 CLA        and restore the file name (if any) to the alpha register
104 ARCL T     from the HP41 stack.
105 ARCL Z
106 OUTA       and send the filename to the HP71
107 RTN 
************************************
* The purpose of PR71 is to put your HP71 to work as a PRINTER device for the
* HP41. The big difference is that instead of actually printing the output,
* your HP71 saves all the output in a text file which is given the name found
* in the HP41's alpha register.  The HP71 remains in printer mode until the 
* HP41 releases it for other work with the PREND program.
108*LBL "PR71"          routine to set-up the HP71 as a printer for the HP41
109 XEQ 99     routine  set-up
110 "5"
111 XEQ 90
    SF 21      otherwise, printed output only goes to the display (bug fix)
112 RTN        That's all! The hard work is done by the HP71
113*LBL "PREND"        Tell the HP71 it no longer has to act as a printer.
114 "  "       F2 FF FF - must be exactly CHR$(255)&CHR$(255)
115 CF 17      so that CR/LF is sent out to terminate ENTER
116 OUTA
117 RTN        Here, we could easily send the file name back to the 41, as a 
* reminder.
*
* PR71 was the first routine developed in this set. I wanted a clean method
* that would allow me to comment program output for stuff I do at work.
* One thing led to another....
* Needles to say, you can intercept most anything, to include the printed
* output of another HP71, or most interfaces.
******************************
118*LBL "PURPR"         PURge an HP41 program file from the PR41 file
119 XEQ 99     this became a neccesity, once STOP and LOADP were implemented.
120 "6"        All you have to do is tell the HP71 what to do.
121 XEQ 90
122 RTN
123*LBL "DIR71"         This tells you what is to be found in HP71 memory
124 XEQ 99     that is of interest to HP41 users, starting with the program
125 "0"        files stored in PR71 (which may be kept in IRAM for safety)
126 OUTA       and ending with any TEXT or SDATA file in MAIN memory. 
127 CLA        The HP71 program needs work to allow access to all IRAM
128*LBL 11     get each "directory" entry, one at a time.
129 FS? 09     if flag 09 is set, stop until R/S is pressed
130 STOP
131 CF 21      display  the Alpha Register, but do NOT send it to a printer!
132 AVIEW      otherwise, XFER41 (HP71) becomes considerably more complicated.
133 CF 17      we want INA to stop when it gets CR/LF
134 INA        get the directory entry
135 ALENG      is it a null string? (End of Directory?)
136 X>0?
137 GTO 11     yes, prepare for the next entry
138 RTN        no, we are done
139*LBL "FE"   a routine to set Fix/Eng 9 mode, and to insure the display
140*LBL 09     format is compatible with the HP71 ENTER statement (w/o having
141 FIX 9      to use IMAGE statements). This is essential if you want to
142 RCLFLAG    exchange numerical data more or less painlessly.
143 ENG 9
144 40.4
145 STOFLAG    effectively, sets flag 40.
146 RDN        stack managment - keep the HP71 loop address in X when done
147 RDN
148 CF 29      MUST USE A "." RADIX!
149 SF 28      WE DO NOT WANT COMMA SEPARATORS - to the HP71, that is a number
150 RTN        separator that terminates ENTER before the entire number is read
151*LBL "UPDAT"         Upload a Data file from Extended Memory to an HP71 SDATA file
152 XEQ 99     routine set-up
153 "7"        option
154 XEQ 90     routine processing
155 CLX        set file pointer to start of file
156 SEEKPTA
157 FLSIZE     how big is it?
158 XEQ 09     set flags for numerical data transfer
159 CLA        send the file size to the HP71
160 ARCL X
161 OUTA
162 SIGN       use register L as a counter
163*LBL 08     the loop for uploading the data
164 CLA        clear alpha
165 GETX       get the number
166 ARCL X     move it to alpha (We really should have an OUTX function)
167 OUTA       send it to the HP71, with CR/LF (Flag 17 is clear from XEQ 99)
168 DSE L      decrement counter
169 GTO 08     if not yet zero, repeat!
170 INA        no, we are done, get the file name back from the HP71
171 RTN        I wonder how hard it would be to preserve both the stack and alpha?
172*LBL "DNDAT"         well, since we can upload data, we need to be able to
173 XEQ 99     download it as well. This does it.
174 "8"        option
175 XEQ 90     routine
176 EMROOM     how much room do we have?
177 SF 25      in case the file exists
178 CRFLD      create the file, using all available Extended Memory
179 CF 25      allow normal error processing
180 FLSIZE     how big is the file? - if it existed, it may not use all available
181 EMROOM     space. If so, how much do we have left?
182 +          set-up to resize the file as needed
183 CLA        send available space to the HP71
184 ARCL X
185 OUTA
186 INA        get the file name
187 IND        get the desired file size (let the HP71 make any desired decisions)
188 RESZFL     now, finally, resize!
189 SIGN       again, use LAST X as a counter
190 CLX        set pointer to start of file
191 SEEKPTA
192*LBL 07     the loop to download data
193 IND        get the number
194 SAVEX      save it  
195 DSE L      decrement the counter
196 GTO 07     and repeat until done
197 END        that's all!