ADDTEXT and MERGTEXT



Manipulating textfiles with  an HP71 is not the easiest of tasks.  To help out I
offer ADDTEXT  and  MERGTEXT.  The former is entirely my own work but the latter
is a modified version of a program I found on  one of the swapdiscs.  In essence
ADDTEXT adds textfiles side by side and MERGTEXT adds textfiles end to end. 

Both programs require either TEXTUTIL or EDLEX:  for  lines  115, 121 and 124 in
ADDTEXT and  for  line  106  in  MERGTEXT.   If  you do not have either of these
lexfiles  then  send me an sae for a hexdump which you can turn into  a  lexfile
using MAKELX2 from V7N1P28.  If you include either a card,  a  tape  or a disc I
will record it for you. 

ADDTEXT - The Instructions

To use ADDTEXT simply RUN it.  At the first prompt you should enter the  name of
the 'LHS' file, (the file that is to appear on  the  LHS  of  the combined file,
followed by the name of the 'RHS' file (the file you wish  to  appear on the RHS
of the combined file) and finally the name of the FINAL (combined) file and then
key ENDLINE.  The program will then display the maximum width of the LHS and RHS
files and  prompt you for the width of the LHS and RHS 'columns' in the combined
file.  The original LHS file  will  appear  left-justified in the LHS column and
the RHS file left-justified  in  the  RHS  column.   After the adding process is
complete you will be prompted for a fresh pair of files.  Keying ENDLINE without
entering  any  names  will  terminate  program usage.  The program automatically
takes care of files  of  unequal  length.  There is one limitation - the overall
width  of  the FINAL file can't be more than 96 characters long unless you alter
line 101 (DIM Z$[xx]) accordingly. 

100 ! ADDTEXT
101 DESTROY ALL @ STD @ OPTION BASE 1 @ DIM Z$[96]
102 ON ERROR GOTO 119 @ BEEP 200 @ INPUT "LHS,RHS,Final : ";L$,R$,F$ @ OFF ERROR
103 Q$=L$ @ GOSUB 'WL' @ L0=W @ L1=L @ Q$=R$ @ GOSUB 'WL' @ R0=W @ R1=L
104 IF L1>R1 THEN Q$=R$ @ GOSUB 'ALIN'
105 IF L1<R1 THEN Q$=L$ @ GOSUB 'ALIN'
106 DISP "Max LHS width :";L0 @ DISP  "Max RHS width :";R0
107 BEEP 400 @ INPUT "LHS,RHS cols  : ";L2,R2
108 DIM A$[L0+R0],L3$[L0+L2],R3$[R0+R2]
109 IF L2<L0 THEN 108 ELSE Q$=L$ @ GOSUB 'ASPA'
110 IF R2<R0 THEN 108 ELSE Q$=R$ @ GOSUB 'ASPA'
111 ON ERROR GOTO 112 @ CREATE TEXT FMT @ GOTO 113
112 PURGE FMT @ GOTO 111
113 OFF ERROR @ ASSIGN #1 TO L$ @ ASSIGN #2 TO R$ @ ASSIGN #3 TO FMT
114 FOR I=1 TO FILESZR(L$) @ READ #1;L3$ @ READ #2;R3$ @ Z$=L3$&R3$
115 PRINT #3;Z$ @ NEXT I @ ASSIGN #1 TO * @ ASSIGN #2 TO * @ ASSIGN #3 TO *
116 ON ERROR GOTO 117 @ RENAME FMT TO F$ @ GOTO 118
117 PURGE F$ @ GOTO 116
118 OFF ERROR @ CAT F$ @ DISP @ GOTO 102
119 OPTION BASE 0 @ DELAY 1,.125 @ FIX 2 @ BEEP 800 @ PUT "#43" @ END
120 'WL': L=FILESZR(Q$) @ ASSIGN #1 TO Q$ @ FOR I=1 TO L @ READ #1;Z$
121 W=MAX(W,LEN(Z$)) @ NEXT I @ ASSIGN #1 TO * @ RETURN
122 'ALIN': Z$=" " @ ASSIGN #1 TO Q$ @ RESTORE #1,9999
123 FOR I=1 TO ABS(FILESZR(L$)-FILESZR(R$)) @ PRINT #1;Z$ @ NEXT I
124 ASSIGN #1 TO * @ RETURN
125 'ASPA': ON ERROR GOTO 126 @ CREATE TEXT FMT @ GOTO 127
126 PURGE FMT @ GOTO 127
127 ASSIGN #1 TO Q$ @ ASSIGN #2 TO FMT @ FOR I=1 TO FILESZR(Q$)
128 Z$="" @ READ #1;Z$ @ FOR J=1 TO L2 @ Z$=Z$&" " @ NEXT J
129 Z$=Z$[1,L2] @ PRINT #2;Z$ @ NEXT I
130 ASSIGN #1 TO * @ ASSIGN #2 TO * @ PURGE Q$ @ RENAME FMT TO Q$ @ RETURN

MERGTEXT - The Instructions

MERGTEXT is much easier to use.  Just  RUN  the  program and at the prompt enter
the  names of the two files you want to merge and key ENDLINE.  The SECOND  file
will  be  merged  into  the FIRST file.  When the merging is complete the SECOND
file will be automatically deleted and you will be  prompted for a fresh pair of
files.  Keying ENDLINE without entering any filenames terminates program  usage.
MERGTEXT has one limitation - the maximum line length in the  SECOND  file is 96
characters unless you change line 101 (DIM Z$[xx]) accordingly. 

100 ! MERGTEXT
101 DESTROY ALL @ DIM A$[96]
102 ON ERROR GOTO 108 @ BEEP 200 @ INPUT "Merge : ";W$,M$
103 OFF ERROR @ CAT W$ @ WAIT 1 @ CAT M$ @ WAIT 1
104 ASSIGN #1 TO M$ @ ASSIGN #2 TO W$ @ RESTORE #1,1 @ RESTORE #2,9999
105 FOR I=0 TO FILESZR(M$)-1 @ READ #1,I;A$ @ PRINT #2;A$ @ NEXT I
106 ASSIGN #1 TO * @ ASSIGN #2 TO *
107 PURGE M$ @ DISP @ CAT W$ @ DISP @ GOTO 102
108 OFF ERROR @ BEEP 800 @ PUT "#43" @ END

I hope you find these programs of some use.  Your comments are encouraged. 

Mark Cracknell [#129A]