LEX    'COMBARR'

* (c) PPC-Paris 1987

       ID     #E1
       MSG    0
       POLL   0
AD2-15 EQU    #0C363
ARGERR EQU    #0BF19
CLRFRC EQU    #0C6F4
DV2-15 EQU    #0C4AC
EXAB1  EQU    #0D3E7
EXAB2  EQU    #0D40E
FNRTN4 EQU    #0F238
FUNCD0 EQU    #2F8BB
MP2-15 EQU    #0C43A
POP1R  EQU    #0E8FD
RCCD1  EQU    #0D3F5
RCCD2  EQU    #0D41C
RCLW1  EQU    #0E981
SPLITA EQU    #0C6BF
STAB1  EQU    #0D3D9
STAB2  EQU    #0D400
STSCR  EQU    #0E92C
SUBONE EQU    #0C327
TST15  EQU    #0D47A
uRES12 EQU    #0C994
       ENTRY  AR
       CHAR   #F
       ENTRY  CMB
       CHAR   #F
       KEY    'ARR'
       TOKEN  20
       KEY    'COMB'
       TOKEN  21
       ENDTXT
       NIBHEX 8822
AR     ST=0   0
       GONC   START
       NIBHEX 8822
CMB    ST=1   0
START  GOSUB  POP
       GOSBVL STAB2
       ?B=0   W
       GOYES  C1
       D1=D1+ 16
       GOSUB  POP
       GOSBVL STAB1
       GOSBVL RCCD2
       P=     2
       GOSBVL TST15
       GONC   P6
       ?ST=0  0
       GOYES  P6
C1     C=0    W
       P=     1
       C=P    14
       GOTO   FNRTN
P6     P=     6
       GOSBVL TST15
       GOC    CONT
       GOTO   ERR
CONT   ?ST=0  0
       GOYES  ar
       C=C-1  S
       GOSBVL AD2-15
       GOSBVL RCCD2
       P=     1
       GOSBVL TST15
       GONC   ar
       GOSBVL EXAB2
ar     AD0EX
       D0=(5) (FUNCD0)
       DAT0=A A
       A=0    W
       B=0    W
       P=     14
       B=B+1  P
       GOSBVL STSCR
LOOP
       GOSBVL RCLW1
       GOSBVL RCCD1
       GOSBVL MP2-15
       GOSBVL RCCD2
       ?ST=0  0
       GOYES  NODIV
       GOSBVL DV2-15
NODIV  GOSBVL STSCR
       GOSBVL EXAB2
       GOSBVL SUBONE
       ?B=0   W
       GOYES  OUT
       GOSBVL EXAB2
       GOSBVL EXAB1
       GOSBVL SUBONE
       GOSBVL EXAB1
       GOTO   LOOP
OUT    GOSBVL RCLW1
       D0=(5) (FUNCD0)
       C=DAT0 A
       D0=C
       GOSBVL uRES12
FNRTN  GOVLNG FNRTN4
POP    GOSBVL POP1R
       ?A#0   S
       GOYES  ERR
       LCHEX  011
       ?A>C   X
       GOYES  ERR
       GOSBVL SPLITA
       GOSBVL CLRFRC
       RTNC
ERR    GOVLNG ARGERR
       END
Guy TOUBLANC (P276) 4/12/86