LEX    'EDIT'
* (c) Copyright PPC Paris 1986
        ID     1
        MSG    0
        POLL   0
        ENTRY  EDITe
        CHAR   5        Non programmable
        KEY    'EDIT'   Ecrase la fonction
        TOKEN  184      originelle.

BSERR   EQU    #0939A
COPYu   EQU    #08269
CRETF+  EQU    #084C4
CURDVC  EQU    #0A60B
CURRST  EQU    #2F55D
EDIT80  EQU    #0A5A5
EDITWF  EQU    #0A533
EOLCK   EQU    #02A7E
FINDF+  EQU    #09F63
FLDEVX  EQU    #01154
FSPECe  EQU    #02F02
FSPECp  EQU    #03CC5
FSPECx  EQU    #09F2D
NXTSTM  EQU    #08A48
RDINFO  EQU    #0846B
RESPTR  EQU    #03172
SALLOC  EQU    #0153B
SVINFO  EQU    #0845A
WRDSCN  EQU    #02C2A
dCARD   EQU    #00007
eFSPEC  EQU    #0003A
fBASIC  EQU    #0E214
lDATEh  EQU    #00006
lFILSV  EQU    #00032
lFLAGh  EQU    #00002
lFLENh  EQU    #00005
lFNAMh  EQU    #00010
lFTYPh  EQU    #00004
lTIMEh  EQU    #00004
oBSsod  EQU    #00011
oFLENh  EQU    #00020
sDEST   EQU    #00003
tCARD   EQU    #000D0
tEOL    EQU    #000F0
tKEYS   EQU    #000CF
tTO     EQU    #000F3
        ENDTXT

        REL(5) EDITP

EDITe   LC(5)  lFILSV   RÅserve 50 quartets
        P=     1        pour la SAVSTK
        GOSBVL SALLOC   (= zone de sauvegarde)
        GOC    jp       INSUFFICENT MEMORY
CPY010  D=0    W        PÅriphÅrique initialisÅ
        LCASC  '  '     CaractÉres 9 et 10
        R0=C            du nom du fichier ÅffacÅs
        A=DAT0 B        Lit token suivant

**************************************************
* COPY TO  /  COPY <spec> TO ...
**************************************************
        LC(2)  tTO
        ?A#C   B        Token <> TO ?
        GOYES  CPY030
        D0=D0+ 2        Saute TO token
        ?ST=1  sDEST    Destination ?
        GOYES  CPY040   Analyse N2:P2

**************************************************
*
* COPY  TO  ...
* Pas de fichier source spÅcifiÅ
* Prend le fichier et spÅcificateur courant
*
**************************************************
CPY020  GOSUB  deffil   N1:P1 <-- courant
        GONC   CPY065   B.E.T.

**************************************************
*
* EDIT avec/sans paramÉtres  /  EDIT <spec> EOL
*
*    Si Source
*      EDIT workfile
*    Sinon       (CPY045)
*      N2:P2 <-- 0
*      Si N1 pas en mÅmoire
*         Recopier N1  (CPY080)
*      EDIT N1   (edit80)
*
**************************************************
        *
CPY030  LCHEX  F0       Token <> EOL ?
        ?A<C   B
        GOYES  CPY040   oui
        ?ST=1  sDEST    Destination ?
        GOYES  CPY045

        *
        * EDIT workfile
        *
        GOVLNG EDITWF

**************************************************
* COPY ... CARD
**************************************************
CPY040  LC(2)  tCARD    CARD token ?
        ?A#C   B
        GOYES  CPY060   non
        LC(1)  dCARD
        D=C    P        PÅriphÅrique= :CARD
CPY050  D0=D0+ 2        Saute token
        A=0    W        Pas de nom
        GONC   CPY070   B.E.T.

CPY060  GOSUB  tkysck   KEYS token ?
        GONC   CPY065   oui
        GOSBVL FSPECx   Analyse spÅcificateur
jp      GOC    EDIT79   ILLEGAL FILESPEC

CPY065  DSLC            SpÅcificateur en D[A] et
CPY070  GOSBVL SVINFO   nom en A[W]&R0 sauvÅs.
        ?ST=1  sDEST    Destination ?
        GOYES  CPY071   alors analyse terminÅe
        ST=1   sDEST    Sinon il reste
        GOTO   CPY010   ... TO N2:P2 È examiner
CPY071  GOTO   CPY80+

**************************************************
*
* EDIT  N1:P1
*
* EntrÅe:  sDEST=1  ;  D[W]=0
**************************************************
        *
CPY045  D0=D0+ 2
        A=0    W        Pas de fichier objet prÅcisÅ
        GOSBVL SVINFO   N2:P2 <-- 0
        ST=0   sDEST
        GOSBVL RDINFO   A[W] <-- N1 ; D[A] <-- P1
        DSRC            D[S]= spÅcificateur
        C=D    W
        R3=C
        GOSBVL FINDF+   N1 en mÅmoire ?
        GONC   edit80   oui
        ?ST=0  6        N1= 0 ou P1= externe ?
        GOYES  CPY080
        C=R3            CrÅe le fichier N1
        D=C    W        en respectant P1
        R2=A
        C=0    A
        LC(2)  (oFLENh)+(oBSsod)
        GOSBVL CRETF+
EDIT79  GOC    CPYERX
        A=R1
        D1=A
        C=R2
        DAT1=C lFNAMh
        D1=D1+ lFNAMh
        LC(4)  fBASIC
        DAT1=C lFTYPh
        D1=D1+ (lFTYPh)+(lTIMEh)+(lDATEh)+(lFLAGh)
        D1=D1+ lFLENh
        C=0    W
        DAT1=C 10
        D1=D1+ 10
        LC(2)  tEOL
        DAT1=C B
        D1=A

        *
        * Edite le fichier pointÅ par D1
        *
edit80  GOSBVL EDIT80
        GOVLNG NXTSTM   FIN

**************************************************
*
* COPY N1:P1 TO N2:P2  et  EDITE N2:P2
*
* 1) Recopie N1:P1 dans N2:P2
* 2) Puis Ådite N2
*
* EntrÅe: suppose P2= pÅriph. interne
**************************************************
        *
CPY080  GOSBVL COPYu
        GOC    CPYERX   Erreur
        C=R1            R1 ^ fichier copiÅ
        D1=C            D1 <-- R1
        GONC   edit80   B.E.T.

        * Teste si P2= PÅriphÅrique interne
        *     oui -> CPY080
        *     non -> ILLEGAL FILESPEC
        * EntrÅe: D[A] = :P2
        *
CPY80+  DSRC            D[S]= type de P2
        D=D+1  S        P2 indÅfini ?
        GOC    CPY080   MAIN par dÅfaut
        D=D+D  S        externe ?
        GONC   CPY080   non
        LC(4)  eFSPEC   ILLEGAL FILE SPECIFIER
CPYERX  GOVLNG BSERR    Basic Error

deffil  GOSBVL CURDVC   Trouve pÅriphÅrique
        GOSBVL FLDEVX   courant
        D1=(5) CURRST
        C=DAT1 A
        D1=C            D1 @ sommet fichier courant
        A=DAT1 W        A[W] <-- nom du fichier
        LCASC  '  '
        R0=C            cf. CPY010
        RTNCC

tkysck  A=DAT0 B
        LC(2)  tKEYS
        ?A#C   B
        RTNYES
        D0=D0+ 2        Saute token
        LCASC  '    syek'
        D=0    S
        A=C    W
        RTN

*
******* ROUTINE DE PARSE *******
*
EDITP   GOSUB  eolck+
        GOC    NAMEP7
        GONC   EDP10    B.E.T.
RNMP05  ST=1   8
EDP10   GOSBVL FSPECp
        GONC   RNMP25
        GOVLNG FSPECe

RNMP25  ?ST=1  8
        GOYES  LSTPDN
        GOSBVL WRDSCN
        CON(2) tTO
        REL(5) RNMP05
        CON(2) 0
NAMEP7  GOVLNG RESPTR
LSTPDN  RTNCC
eolck+  GOSBVL EOLCK
        RTNC
        GONC   NAMEP7   B.E.T.

        END