LEX    'BURNLEX'
       ID     #88
       MSG    0
       POLL   0
*
       ENTRY  BINCMP
       CHAR   #F
       ENTRY  HTA
       CHAR   #F
       ENTRY  STRSUM
       CHAR   #F
*
       KEY    'BINCMP$'
       TOKEN  1
       KEY    'HTA$'
       TOKEN  2
       KEY    'STRSUM'
       TOKEN  3
       ENDTXT
*
ARGERR EQU #0BF19
CONVUC EQU #152AA
DRANGE EQU #1B076
EXPR   EQU #0F23C
FNRTN4 EQU #0F238
HDFLT  EQU #1B31B
POP1S  EQU #0BD38
RANGE  EQU #1B07C
****
       NIBHEX 411
HTA    GOSBVL POP1S
       C=A    A
       ST=C
       ?ST#0  1
       GOYES  Argerr
       CD0EX
       RSTK=C
       CD1EX
       C=C+A  A
       D0=C
       D1=C
       C=0    M
       C=A    A
       CSRB
       CSRB
       D=C    A
       C=C+C  A
       CSL    W
       CSL    W
       C=C-1  P
       R1=C
LOOP1  D=D-1  A
       GOC    HTAFIN
       D0=D0- 4
       A=DAT0 4
       P=     1
       GOSUB  CONVAH
       D1=D1- 2
       DAT1=A B
       GONC   LOOP1
HTAFIN C=RSTK
       D0=C
       D1=D1- 16
       C=R1
       GOVLNG FNRTN4
Argerr GOVLNG ARGERR
CONVAH C=P    15
       P=     0
BCL1   GOSBVL DRANGE
       GONC   CVH10
       GOSBVL CONVUC
       LCASC  'FA'
       GOSBVL RANGE
       GOC    Argerr
       LC(1)  9
       A=A+C  P
CVH10  BSL    W
       B=A    P
       ASR    W
       ASR    W
       C=C-1  S
       GONC   BCL1
       A=B    W
       RTNCC
****
       NIBHEX 411
BINCMP GOSBVL POP1S
       ?A=0   A
       GOYES  EXIT1
       B=A    A
       CD1EX
       C=C+A  A
       D1=C
LOOP2  D1=D1- 2
       A=DAT1 B
       A=-A-1 B
       DAT1=A B
       B=B-1  A
       B=B-1  A
       ?B#0   A
       GOYES  LOOP2
EXIT1  D1=D1- 16
FNRTN  GOVLNG EXPR
****
       NIBHEX 411
STRSUM GOSBVL POP1S
       CD1EX
       C=C+A  A
       D1=C
       D=C    A
       B=A    A
       A=0    A
       C=0    A
LOOP3  ?B=0   A
       GOYES  DONE
       D1=D1- 2
       C=DAT1 B
       A=A+C  A
       B=B-1  A
       B=B-1  A
       GONC   LOOP3
DONE   C=D    A
       D1=C
       GOSBVL HDFLT
       D1=D1- 16
       DAT1=A W
       GONC   FNRTN
       END