LEX 'HMSHRLEX'
  TITLE DEGREES TO DECIMAL CONVERSIONS
      ID #50
      MSG 0
      POLL 0
CPOLLF EQU #0BC20
MPOP1N EQU #0BD8D
OUTRES EQU #0BC84
SPLITA EQU #0C6BF
  EJECT
      ENTRY HMS
      CHAR #F
      ENTRY HR
      CHAR #F
  EJECT
      KEY 'HMS'
      TOKEN 1
      KEY 'HR'
      TOKEN 2
      ENDTXT
  EJECT
      NIBHEX 8
      NIBHEX 11
HMS   GOSUB GET1N
      ST=1 5
      GOSUB CONVRT
      GOTO ANSWER
  *
      NIBHEX 8
      NIBHEX 11
HR    GOSUB GET1N
      ST=0 5
      GOSUB CONVRT
      GOTO ANSWER
  EJECT
GET1N GOSBVL MPOP1N       GET NUMBER FROM STACK
      GONC SPLIT          JUMP IF NOT COMPLEX
      C=RSTK              COMPLEX, SO DROP RETURN
      GOVLNG CPOLLF
SPLIT GOSBVL SPLITA       SPLIT & RETURN
      RTN
ANSWER GOVLNG OUTRES      PUT ANSWER ONTO STACK
  STITLE DMS-DEC, DEC-DMS ROUTINE
  * INPUT 15-FORM IN A & B
  * FLAG 5 CLEAR IF CONVERTING TO DECIMAL
  * FLAG 5 SET IF CONVERTING FROM DECIMAL
  *
  * OUTPUT 15-FORM IN A AND B
  *
  * USES A(W) B(W) C(W) D(A) P, 2 LEVELS
  * CALLS NOTHING
  *
  *
CONVRT XM=0                HMS-HR & HR-HMS
      C=A W
      P= 14
      ?B=0 WP            RETURN IF MANTISSA ZERO
      RTNYES
      C=C+1 A
      C=C+1 A
      D=C A
      D=D+C A
      GOC HMS140
HMS110 P=P-1
      ?P= 0
      RTNYES                 RETURN IF WHOLE DEGREES
      C=C-1 A
      GONC HMS110
HMS140 ?ST=0 5          TO DECIMAL?
      GOYES HRS100
      P=P+1
      ?P# 15
      GOYES HMS150
      GOSUB HMSMP
      GOTO HMS160
HMS150 P=P+1
      GOSUB HMSMP
      P=P-1
HMS160 P=P-1
      GOSUB HMSMP
      RTN            RETURN- ANSWER IN DD.MMSSsssss FORM
HRS100 C=0 W
      GOSUB HMSDV
      P=P+1
      ?P= 15
      GOYES HRS120
      P=P+1
HRS120 GOSUB HMSDV
      CSL W
      B=B+C W
      RTN            RETURN- ANSWER IN DD.ddddddddd FORM
HMSDV BSR WP
      B=B+C WP 
HMSMP C=B WP
      BSR WP
      B=B+B WP
      B=B+B WP
      B=C-B WP
      ?ST=0 5           TO DECIMAL?
      GOYES HMSM20
      C=0 W
      C=B X
      B=B+C W
      B=0 X
      RTN
HMSM20 C=B+C WP
      BSR WP
      ?B#0 WP
      GOYES HMSM20
      RTN
      END